10 * STARWARS
20 *   BY JERRY SELF
30 *   OCTOBER 3, 1977
70 ; "WHAT SIZE GRID DO YOU WANT?  NOVICE=20,20 OR CHALLENGE=20,40."
80 ; "LIMITS ARE 60,60.  SIZE": & INPUT S1,S2
90 W,T1,T2=0 
100 ; "DO YOU WANT INSTRUCTIONS Y/N";
110 INPUT A$ & IF A$="Y" THEN 520
120 DIM G(60,60)
125 * POSITIONING THE TARGET
130 C1=INT(RND(1)*S1) & IF C1=0 THEN 130
140 C2=INT(RND(1)*S2) & IF C2=0 THEN 140
150 T2=T2+1 & F,M,Z=0
155 * INITIALING THE GRID
160 FOR I=1 TO S1
170 FOR J=1 TO S2
180 G(I,J)=" "
190 NEXT J & NEXT I
200 G(C1,C2)=2 & N=11
205 * THE PLAY BEGINS
210 FOR I=1 TO 10
220 N=N-1 & ; N:"MINUTES TIL DEATHSTAR CLEARS PLANET."
230 GOSUB 900
235 * RANDOMIZING HAN SOLO TO THE RESCUE
240 IF Z>0 THEN 250& GOTO 280
250 M=INT(RND(0)+.3) & IF M=1 THEN 260& GOTO 280
260 G(C3,C4)=" " & Z=0
270 ; "HAN SOLO HAS ELIMINATED THE IMPERIAL FIGHTER."
275 *  TARGETING THE BOMB
280 ; & ; "ENTER COORDINATES"; & INPUT X & INPUT Y
290 IF X<1 THEN 280& IF X>S1 THEN 280& IF Y<1 THEN 280& IF Y>S2 THEN 280
300 IF G(X,Y)=2 THEN 420 & IF G(X,Y)=4 THEN 710 & G(X,Y)=1
315 * CHECKING FOR STRIKE
320 FOR J=1 TO 5 
330 IF X+J>S1 THEN 360& IF Y+J>S2 THEN 360
340 IF G(X+J,Y+J)=2 THEN 460& IF G(X+J,Y+J)=4 THEN 710
350 G(X+J,Y+J)=1
360	NEXT J
370 GOSUB 740
380 NEXT I
385 * REPORTING OUTCOME OF GAME
390 ; "THE DEATHSTAR HAS DESTROYED THE REBEL BASE."
400 ; "YOU ARE HOMELESS AND LOSING POWER." & W=-10
410 ; "DARTH VADER WILL GET YOU." & GOTO 480
420 G(X,Y)=3 & GOSUB 740
430 ; "!!!IMMEDIATE DIRECT HIT!!!  YOU HAVE DESTROYED THE DEATHSTAR"
440 : "AND SAVED THE REBEL CAUSE!" & W=N*10
450 GOTO 480
460 G(X+J,Y+J)=3 & GOSUB 740
470 ; "YOU HAVE DESTROYED THE DEATHSTAR!" & W=N*5
480 T1=T1+W & ; "SCORE THIS GAME";W,"TOTAL";T1,"AVERAGE";T1/T2
485 ; "DO YOU WANT TO PLAY AGAIN Y/N";
490 INPUT A$ & IF A$="Y" THEN 130
500 ; "MAY THE FORCE BE WITH YOU"
510 END
515 *  INSTRUCTIONS
520 ; "THE DEATHSTAR HAS THE POWER TO DESTROY A PLANET WITH A"
530 ; "SINGLE BLAST, IT IS APPROACHING THE REBEL BASE WHICH"
540 ; "IS ON A MOON HIDDEN BEHIND THE MOTHER PLANET,  AS SOON AS"
550 ; "THE DEATHSTAR CIRCLES THE PLANET IT WILL DESTROY THE BASE."
560 ; "YOU ARE FLYING A FIGHTER WHICH CAN BOMB A SMALL"
570 ; "SHAFT LEADING TO THE POWER SOURCE OF THE DEATHSTAR."
580 ; "IF YOU HIT IT YOU WILL DESTROY THE DEATHSTAR AND SAVE"
590 ; "THE REBEL BASE." & ;
600 ; "ENTER COORDINATE X (WITHIN GRID LIMIT)  AND Y TO TARGET"
610 ; "YOUR BOMB. THE BOMB TRAJECTORY WILL THEN BE SHOWN"
620 ; "ON YOUR SCREEN. THE TARGET (#) WILL ALSO APPEAR"
630 ; "YOU CAN THEN ESTIMATE HOW MUCH YOU MISSED. THE FIGHTER"
640 ; "IS EQUIPPED WITH A COMPUTERIZED GRID WHICH CAN SHOW THE"
650 ; "EXACT LOCATION OF THE TARGET.  BUT YOU DO NOT USE IT"
660 ; "BECAUSE YOU TRUST THE FORCE."
670 ; "BUT WATCH OUT FOR IMPERIAL FIGHTFRS!"
680 ; "IF YOU OR HAN SOLO DO NOT ELIMINATE THEM WITHIN TWO TURNS,"
690 ; "THEY WILL ELIMINATE YOU. MAY THE FORCE BE WITH YOU!" & ;
700 GOTO 120
705 *  REPORTING STRIKE ON FIGHTER
710 G(C3,C4)=" " & Z=0
720 ; "YOU HAVE HIT THE IMPERIAL FIGHTER." & GOTO 370
735 *  PRINTING THE GRID
740 FOR K=1 TO S1
750 FOR J=1 TO S2
760 IF G(K,J)=1 THEN 810 & IF G(K,J)=2 THEN 820
770 IF G(K,J)=3 THEN 860 & IF G(K,J)=4 THEN 830
800 GOTO 840
810 ; TAB(J)"*"TAB(0) & G(K,J)=" " & GOTO 840
820 ; TAB(J)"#"TAB(0) & GOTO 840 
830 ; TAB(J)"X"TAB(0) & GOTO 840
840 NEXT J K ; & NEXT K & GOTO 890
860 ; "**************************************************************"
870 ; "*********************KABOOM***********************************"
880 ; "**************************************************************"
890 RETURN
900 IF Z>0 THEN 960& *ROUTINE TO RANDOM IMPER. FIGHTER
910 F=INT(RND(0)+.5) & IF F=1 THEN 920& GOTO 1010
920 C3=INT(RND(1)*S1) & IF C3=0 THEN 920
930 C4=INT(RND(1)*S2) & IF C4=0 THEN 930& Z=1
940 G(C3,C4)=4
950 ; "IMPERIAL FIGHTER ON THE ATTACK" & GOTO 1140
960 ON Z GOTO 970,980
970 ; "IMPERIAL FIGHTER PENETRATING SHIELDS" & Z=Z+1 & GOTO 1140
980 ; "THE IMPERIAL FIGHTER HAS DESTROYED YOUR SHIP."
990 ; "THE DEATHSTAR WILL DESTROY THE MOON AND THE REBEL BASE."
1000 W=N*(-10) & GOTO 480
1005 *  PRINTING RADIO MESSAGES
1010 ON N GOTO 1020,1040,1050,1060,1070,1090,1100,1110,1120,1130
1020 ; "THE GRAND MOFF TARKIN HAS ORDERED THE DESTRUCT SEQUENCE"
1030 GOTO 1140
1040 ; "DARTH VADER IS DETERMINED TO GET YOU" & GOTO 1140
1050 ; "THE REBEL CAUSE DEPENDS ON YOU" & GOTO 1140
1060 ; "TRUST THE FORCE" & GOTO 1140
1070 ; "THE TRADITION OF THE JEDI KNIGHTS DEMANDS THAT YOU WIN"
1080 GOTO 1140
1090 ; "REMEMBER THE JAWAS" & GOTO 1140
1100 ; "SOLO'S MILLENIUM FALCON IS STANDING BY" & GOTO 1140
1110 ; "R2D2 IS CORRECTING A MALFUNCTION" & GOTO 1140
1120 ; "C3P0 HAS BROKEN INTO A SWEAT" & GOTO 1140
1130 ; "PRINCESS LEIA RADIOES 'PLEASE HURRY'" & GOTO 1140
1140 RETURN